2102 '	leave a comment
2104 '	1.5
2106 A$=" ":CR%=2: GOSUB 400
2107 IF ASKFORCOM%=0 THEN RETURN
2108 IF ASKFORCOM%<>0 THEN A$="Want to leave a comment (Y or N) > ":
 	CR%=0: GOSUB 400:
 	MAX%=0: GOSUB 500:
 	IF LEFT$(ANSWER$,1) <> "Y" THEN RETURN
2110 PRINT:PRINT
2112 SETUSERNUMBER%=USERNUMBER%: GOSUB 300
2114 OPEN "R", #3, DEFDRIVE$+COMMENTFILE$, 66
2116 FIELD #3,
 	5 AS COMMENTNUMBER$,
 	8 AS TOTCOMMT$,
 	1 AS COMSIG$,
 	6 AS FCOMDATE$,
 	6 AS FCOMTIME$,
 	1 AS FINEWCOM$,
 	1 AS FSYSCOM$
2118 GET #3,1
2120 NEXTCOMMENT%=VAL(COMMENTNUMBER$)
2122 TOTALCOMMENTS#=VAL(TOTCOMMT$)
2124 COMTIME$=FCOMTIME$
2125 NEWCOM$=FINEWCOM$
2126 COMDATE$=FCOMDATE$
2127 SYSCOM$=FSYSCOM$
2128 IF COMSIG$<>"*" THEN 
 	NEXTCOMMENT%=2:
 	TOTALCOMMENTS#=1:
 	GOSUB 1600:
 	COMTIME$=TIME$:
 	COMDATE$=DATE$
2130 FIELD #3, 64 AS COMMENT$, 2 AS CRLF$: LSET CRLF$=CHR$(13)+CHR$(10)
2132 GOSUB 1600
2134 ANSWER$="~"+STR$(TOTALCOMMENTS#)+" from "+FRNAME$+" "+LNAME$
 	+" on " +FNADDSEP$(DATE$,"/")
 	+" at "+FNADDSEP$(TIME$,":")
 	+" ("+NOTATION$+")"
2136 GOSUB 2174
2138 A$="Type your comments at the arrow, press RETURN after":CR%=2:GOSUB 400
2140 A$="each line. Press RETURN with no comment when done.":CR%=2:GOSUB 400
2142 A$=" " : CR%=2: GOSUB 400
2144 NKEY%=1
2146 WHILE NKEY%
2148	A$="> ":CR%=0: GOSUB 400
2150	MAX%=64: KEEPLOWER%=1: GOSUB 700
2152	IF NKEY%<>0 THEN GOSUB 2174
2154 WEND
2158 LSET COMMENTNUMBER$ = STR$(NEXTCOMMENT%)
2160 LSET TOTCOMMT$ = STR$(TOTALCOMMENTS#+1)
2162 LSET COMSIG$="*"
2164 LSET FCOMDATE$ = COMDATE$
2165 LSET FINEWCOM$="*"
2166 LSET FCOMTIME$ = COMTIME$
2167 LSET FSYSCOM$=SYSCOM$
2168 PUT #3,1
2170 CLOSE #3
2172 RETURN
2174 LSET COMMENT$ = ANSWER$
2176 PUT #3, NEXTCOMMENT%
2178 NEXTCOMMENT%=NEXTCOMMENT%+1
2180 RETURN