1000	REM	SCAN
	INPUT "FILENAME: ";FILENAME$
	FILEOUT$=FILENAME$
	DIM	FLAGS(20)
	DIM CALL$(20),NAME$(20),QTH$(20),FREQ$(20),DATE$(20),TIME$(20),CARD$(20)
	K=20
	OUTCNT=0
	COUNTER=0
	FILE	FILENAME$
	FILE	FILEOUT$
 
1010	REM
	FOR J=1 TO 20
	FLAGS(J)=0
	NEXT J
 
	FOR J=1 TO 20
	READ #1; CALL$(J),NAME$(J),QTH$(J),FREQ$(J),\
	DATE$(J),TIME$(J),CARD$(J)
	IF CALL$(J)="END" THEN 1020
	COUNTER=COUNTER+1
	NEXT J
1020	GOSUB 1065
1033	REM
	PRINT
	PRINT "0=END PAGE / 1-20=DELETE ITEM / 21=RESTART / 22=CHANGE"
 
1035	REM
	INPUT ANSWER
	IF ANSWER = 0 THEN 1040
	IF ANSWER = 21 THEN 1055
	IF ANSWER = 22 THEN 1500
	IF ANSWER > 20 THEN 1035
	IF ANSWER <1   THEN 1035
	FLAGS(ANSWER)=1
	GOTO 1035
 
1040	REM
	FOR J=1 TO K
	IF FLAGS(J) <> 0 THEN 1045
	PRINT #2; CALL$(J),NAME$(J),QTH$(J),FREQ$(J),\
	DATE$(J),TIME$(J),CARD$(J)
	IF CALL$(J)="END" THEN 1022
	OUTCNT=OUTCNT+1
1045	REM
	NEXT J
	GOTO 1010
 
1055	REM
	FOR J=1 TO 20
	FLAGS(J)=0
	NEXT J
	GOSUB 1065
	GOTO 1033
 
1065	REM	LIST
	PRINT CHR$(26)
	FOR J=1 TO 20
	IF CALL$(J)="END" THEN 1070
	GOSUB 1700
	NEXT J
1070	RETURN
 
1022	REM	END OF JOB ROUTINE
	PRINT "END OF LIST"
	PRINT COUNTER;" INPUT ITEMS"
	PRINT OUTCNT;" OUTPUT ITEMS"
	CLOSE 1:CLOSE 2
	GOTO 1999

1500	REM CHANGE 
	INPUT "Which item/number to change?";J
	GOSUB 1600
1510	INPUT "Which above field to change?";F$
	INPUT "New entry: ";N$
	IF F$="CALL" THEN CALL$(J)=N$
	IF F$="NAME" THEN NAME$(J)=N$
	IF F$="QTH" THEN QTH$(J)=N$
	IF F$="FREQ" THEN FREQ$(J)=N$
	IF F$="DATE" THEN DATE$(J)=N$
	IF F$="TIME" THEN TIME$(J)=N$
	IF F$="CARD" THEN CARD$(J)=N$
	GOSUB 1700
	INPUT "More field change? (Y/N)";A$
	IF A$="Y" THEN GOTO 1510
	INPUT "More number/items to change? (Y/N)";A$
	IF A$="Y" THEN GOTO 1500
	GOTO 1055
1600	PRINT "CALL";TAB(12);"NAME";TAB(23);"QTH";TAB(37);"FREQ";\
		TAB(47);"DATE";TAB(57);"TIME";TAB(63);"CARD"
1700	PRINT J;CALL$(J);TAB(12);NAME$(J);TAB(23);QTH$(J);TAB(37);\
	FREQ$(J);TAB(47);DATE$(J);TAB(57);TIME$(J);TAB(63);CARD$(J)
	RETURN
1999	GOTO 2